Adapt OMAP44xx spec to new sockeye
[barrelfish] / tools / sockeye / SockeyeParser.hs
1 {-
2   SockeyeParser.hs: Parser for Sockeye
3
4   Part of Sockeye
5
6   Copyright (c) 2017, ETH Zurich.
7
8   All rights reserved.
9
10   This file is distributed under the terms in the attached LICENSE file.
11   If you do not find this file, copies can be found by writing to:
12   ETH Zurich D-INFK, CAB F.78, Universitaetstr. 6, CH-8092 Zurich,
13   Attn: Systems Group.
14 -}
15
16 module SockeyeParser
17 ( parseSockeye ) where
18
19 import Text.Parsec
20 import qualified Text.Parsec.Token as P
21 import Text.Parsec.Language (javaStyle)
22
23 import qualified SockeyeASTParser as AST
24
25 {- Parser main function -}
26 parseSockeye :: String -> String -> Either ParseError AST.SockeyeSpec
27 parseSockeye = parse sockeyeFile
28
29 {- Sockeye parsing -}
30 sockeyeFile = do
31     whiteSpace
32     spec <- sockeyeSpec
33     eof
34     return spec
35
36 sockeyeSpec = do
37     imports <- many imports
38     modules <- many sockeyeModule
39     net <- many netSpecs
40     return AST.SockeyeSpec
41         { AST.imports = imports
42         , AST.modules = modules
43         , AST.net     = concat net
44         }
45
46 imports = do
47     reserved "import"
48     path <- try importPath <?> "import path"
49     return $ AST.Import path
50
51
52 sockeyeModule = do
53     reserved "module"
54     name <- moduleName
55     params <- option [] $ parens (commaSep moduleParam)
56     body <- braces moduleBody
57     return AST.Module
58         { AST.name       = name
59         , AST.parameters = params
60         , AST.moduleBody = body
61         }
62
63 moduleParam = do
64     paramType <- choice [intType, addrType] <?> "parameter type"
65     paramName <- parameterName
66     return AST.ModuleParam
67         { AST.paramName = paramName
68         , AST.paramType = paramType 
69         }
70     where
71         intType = do
72             symbol "nat"
73             return AST.NaturalParam
74         addrType = do
75             symbol "addr" 
76             return AST.AddressParam
77
78 moduleBody = do
79     ports <- many portDefs
80     net <- many netSpecs
81     return AST.ModuleBody
82         { AST.ports     = concat ports
83         , AST.moduleNet = concat net
84         }
85
86 portDefs = choice [inputPorts, outputPorts]
87     where
88         inputPorts = do
89             reserved "input"
90             commaSep1 inDef
91         inDef = do
92             (forFn, portId) <- identifierFor
93             symbol "/"
94             portWidth <- decimal <?> "number of bits"
95             let
96                 portDef = AST.InputPortDef portId portWidth
97             case forFn of
98                 Nothing -> return portDef
99                 Just f  -> return $ AST.MultiPortDef (f portDef)
100         outputPorts = do
101             reserved "output"
102             commaSep1 outDef
103         outDef = do
104             (forFn, portId) <- identifierFor
105             symbol "/"
106             portWidth <- decimal <?> "number of bits"
107             let
108                 portDef = AST.OutputPortDef portId portWidth
109             case forFn of
110                 Nothing -> return portDef
111                 Just f  -> return $ AST.MultiPortDef (f portDef)
112
113 netSpecs = choice [ inst <?> "module instantiation"
114                  , decl <?> "node declaration"
115                  ]
116     where
117         inst = do
118             moduleInst <- moduleInst
119             return $ [AST.ModuleInstSpec moduleInst]
120         decl = do
121             nodeDecls <- nodeDecls
122             return $ [AST.NodeDeclSpec decl | decl <- nodeDecls]
123
124 moduleInst = do
125     (name, args) <- try $ do
126         name <- moduleName
127         args <- option [] $ parens (commaSep moduleArg)
128         symbol "as"
129         return (name, args)
130     (forFn, namespace) <- identifierFor
131     portMappings <- option [] $ symbol "with" *> many1 portMapping
132     return $ let
133         moduleInst = AST.ModuleInst
134             { AST.moduleName = name
135             , AST.namespace  = namespace
136             , AST.arguments  = args 
137             , AST.portMappings = portMappings
138             }
139         in case forFn of
140             Nothing -> moduleInst
141             Just f  -> AST.MultiModuleInst $ f moduleInst
142
143 moduleArg = choice [addressArg, numberArg, paramArg]
144     where
145         addressArg = do
146             addr <- addressLiteral
147             return $ AST.AddressArg addr
148         numberArg = do
149             num <- numberLiteral
150             return $ AST.NaturalArg num
151         paramArg = do
152             name <- parameterName
153             return $ AST.ParamArg name
154
155 portMapping = choice [inputMapping, outputMapping]
156     where
157         inputMapping = do
158             (forFn, mappedId) <- try $ identifierFor <* symbol ">"
159             portId <- identifier
160             return $ let
161                 portMap = AST.InputPortMap
162                     { AST.mappedId   = mappedId
163                     , AST.mappedPort = portId
164                     }
165                 in case forFn of
166                     Nothing -> portMap
167                     Just f  -> AST.MultiPortMap $ f portMap
168         outputMapping = do
169             (forFn, mappedId) <- try $ identifierFor <* symbol "<"
170             portId <- identifier
171             return $ let
172                 portMap = AST.OutputPortMap
173                     { AST.mappedId   = mappedId
174                     , AST.mappedPort = portId
175                     }
176                 in case forFn of
177                     Nothing -> portMap
178                     Just f  -> AST.MultiPortMap $ f portMap
179
180 nodeDecls = do
181     nodeIds <- choice [try single, try multiple]
182     nodeSpec <- nodeSpec
183     return $ map (toNodeDecl nodeSpec) nodeIds
184     where
185         single = do
186             nodeId <- identifier
187             reserved "is"
188             return [(Nothing, nodeId)]
189         multiple = do
190             nodeIds <- commaSep1 identifierFor
191             reserved "are"
192             return nodeIds
193         toNodeDecl nodeSpec (forFn, ident) = let
194             nodeDecl = AST.NodeDecl
195                 { AST.nodeId = ident
196                 , AST.nodeSpec = nodeSpec
197                 }
198             in case forFn of
199                 Nothing -> nodeDecl
200                 Just f  -> AST.MultiNodeDecl $ f nodeDecl
201
202 identifier = do
203     (_, ident) <- identifierHelper False
204     return ident
205
206 nodeSpec = do
207     nodeType <- optionMaybe $ try nodeType
208     accept <- option [] accept 
209     translate <- option [] tranlsate 
210     overlay <- optionMaybe overlay
211     return AST.NodeSpec 
212         { AST.nodeType  = nodeType
213         , AST.accept    = accept
214         , AST.translate = translate
215         , AST.overlay   = overlay
216         }
217     where
218         accept = do
219             reserved "accept"
220             brackets $ many blockSpec
221         tranlsate = do
222             reserved "map"
223             specs <- brackets $ many mapSpecs
224             return $ concat specs
225
226 nodeType = choice [memory, device]
227     where memory = do
228             symbol "memory"
229             return AST.Memory
230           device = do
231             symbol "device"
232             return AST.Device
233
234 blockSpec = choice [range, length, singleton]
235     where
236         singleton = do
237             address <- address
238             return $ AST.SingletonBlock address
239         range = do
240             base <- try $ address <* symbol "-"
241             limit <- address
242             return $ AST.RangeBlock base limit
243         length = do
244             base <- try $ address <* symbol "/"
245             bits <- decimal <?> "number of bits"
246             return $ AST.LengthBlock base bits
247
248 address = choice [address, param]
249     where
250         address = do
251             addr <- addressLiteral
252             return $ AST.LiteralAddress addr
253         param = do
254             name <- parameterName
255             return $ AST.ParamAddress name
256
257 mapSpecs = do
258     block <- blockSpec
259     reserved "to"
260     dests <- commaSep1 $ mapDest
261     return $ map (toMapSpec block) dests
262     where
263         mapDest = do
264             destNode <- identifier
265             destBase <- optionMaybe $ reserved "at" *> address
266             return (destNode, destBase)
267         toMapSpec block (destNode, destBase) = AST.MapSpec
268             { AST.block    = block
269             , AST.destNode = destNode
270             , AST.destBase = destBase
271             }
272
273 overlay = do
274     reserved "over"
275     over <- identifier
276     symbol "/"
277     width <- decimal <?> "number of bits"
278     return AST.OverlaySpec
279         { AST.over  = over
280         , AST.width = width
281         }
282
283 identifierFor = identifierHelper True
284
285 forVarRange optVarName
286     | optVarName = do 
287         var <- option "#" (try $ variableName <* reserved "in")
288         range var
289     | otherwise = do
290         var <- variableName
291         reserved "in"
292         range var
293     where
294         range var = brackets (do
295             start <- index
296             symbol ".."
297             end <- index
298             return AST.ForVarRange
299                 { AST.var   = var
300                 , AST.start = start
301                 , AST.end   = end
302                 }
303             )
304             <?> "range ([a..b])"
305         index = choice [numberIndex, paramIndex]
306         numberIndex = do
307             num <- numberLiteral
308             return $ AST.LiteralLimit num
309         paramIndex = do
310             name <- parameterName
311             return $ AST.ParamLimit name
312
313 {- Helper functions -}
314 lexer = P.makeTokenParser (
315     javaStyle  {
316         {- list of reserved Names -}
317         P.reservedNames = keywords,
318
319         {- valid identifiers -}
320         P.identStart = letter,
321         P.identLetter = identLetter,
322
323         {- comment start and end -}
324         P.commentStart = "/*",
325         P.commentEnd = "*/",
326         P.commentLine = "//",
327         P.nestedComments = False
328     })
329
330 whiteSpace    = P.whiteSpace lexer
331 reserved      = P.reserved lexer
332 parens        = P.parens lexer
333 brackets      = P.brackets lexer
334 braces        = P.braces lexer
335 symbol        = P.symbol lexer
336 commaSep      = P.commaSep lexer
337 commaSep1     = P.commaSep1 lexer
338 identString    = P.identifier lexer
339 hexadecimal   = symbol "0" *> P.hexadecimal lexer <* whiteSpace
340 decimal       = P.decimal lexer <* whiteSpace
341
342 keywords = ["import", "module",
343             "input", "output",
344             "in",
345             "as", "with",
346             "is", "are",
347             "accept", "map",
348             "over",
349             "to", "at"]   
350
351 identStart     = letter
352 identLetter    = alphaNum <|> char '_' <|> char '-'
353
354 importPath     = many (identLetter <|> char '/') <* whiteSpace
355 moduleName     = identString <?> "module name"
356 parameterName  = identString <?> "parameter name"
357 variableName   = identString <?> "variable name"
358 identifierName = try ident <?> "identifier"
359     where
360         ident = do
361             start <- identStart
362             rest <- many identLetter
363             let ident = start:rest
364             if ident `elem` keywords
365                 then unexpected $ "reserved word \"" ++ ident ++ "\""
366                 else return ident
367
368 numberLiteral  = try decimal <?> "number literal"
369 addressLiteral = try hexadecimal <?> "address literal (hex)"
370
371 identifierHelper inlineFor = do
372     (varRanges, Just ident) <- choice [template identifierName, simple identifierName] <* whiteSpace
373     let
374         forFn = case varRanges of
375          [] -> Nothing
376          _  -> Just $ \body -> AST.For
377                 { AST.varRanges = varRanges
378                 , AST.body      = body
379                 }
380     return (forFn, ident)
381     where
382         simple ident = do
383             name <- ident
384             return $ ([], Just $ AST.SimpleIdent name)
385         template ident = do
386             prefix <- try $ ident <* symbol "{"
387             (ranges, varName, suffix) <- if inlineFor 
388                 then choice [forTemplate, varTemplate]
389                 else varTemplate
390             let
391                 ident = Just AST.TemplateIdent
392                     { AST.prefix = prefix
393                     , AST.varName = varName
394                     , AST.suffix = suffix
395                     }
396             return (ranges, ident)
397         varTemplate = do
398             varName <- variableName
399             char '}'
400             (ranges, suffix) <- templateSuffix
401             return (ranges, varName, suffix)
402         forTemplate = do
403             optVarRange <- forVarRange True
404             char '}'
405             (subRanges, suffix) <- templateSuffix
406             return $ let
407                 varName = mapOptVarName subRanges (AST.var optVarRange)
408                 varRange = optVarRange { AST.var = varName }
409                 ranges = varRange:subRanges
410                 in (ranges, varName, suffix)
411         templateSuffix = option ([], Nothing) $ choice
412             [ template $ many identLetter
413             , simple $ many1 identLetter
414             ]
415         mapOptVarName prev "#" = "#" ++ (show $ (length prev) + 1)
416         mapOptVarName _ name = name