Sockeye: Allow to use inlined for in node decls
[barrelfish] / tools / sockeye / SockeyeParser.hs
1 {-
2   SockeyeParser.hs: Parser for Sockeye
3
4   Part of Sockeye
5
6   Copyright (c) 2017, ETH Zurich.
7
8   All rights reserved.
9
10   This file is distributed under the terms in the attached LICENSE file.
11   If you do not find this file, copies can be found by writing to:
12   ETH Zurich D-INFK, CAB F.78, Universitaetstr. 6, CH-8092 Zurich,
13   Attn: Systems Group.
14 -}
15
16 module SockeyeParser
17 ( parseSockeye ) where
18
19 import Control.Monad
20
21 import Data.Maybe (fromMaybe)
22
23 import Text.ParserCombinators.Parsec as Parsec
24 import qualified Text.ParserCombinators.Parsec.Token as P
25 import Text.ParserCombinators.Parsec.Language (javaStyle)
26
27 import qualified SockeyeASTFrontend as AST
28
29 {- Parser main function -}
30 parseSockeye :: String -> String -> Either ParseError AST.SockeyeSpec
31 parseSockeye = parse sockeyeFile
32
33 {- Sockeye parsing -}
34 sockeyeFile = do
35     whiteSpace
36     spec <- sockeyeSpec
37     eof
38     return spec
39
40 sockeyeSpec = do
41     modules <- many sockeyeModule
42     net <- many netSpec
43     return AST.SockeyeSpec
44         { AST.modules = modules
45         , AST.net     = net
46         }
47
48 sockeyeModule = do
49     reserved "module"
50     name <- moduleName
51     params <- option [] $ parens (commaSep moduleParam)
52     body <- braces moduleBody
53     return AST.Module
54         { AST.name       = name
55         , AST.parameters = params
56         , AST.moduleBody = body
57         }
58
59 moduleParam = do
60     paramType <- choice [intType, addrType] <?> "parameter type"
61     paramName <- parameterName
62     return AST.ModuleParam
63         { AST.paramName = paramName
64         , AST.paramType = paramType 
65         }
66     where
67         intType = do
68             symbol "int"
69             return AST.NumberParam
70         addrType = do
71             symbol "addr" 
72             return AST.AddressParam
73
74 moduleBody = do
75     ports <- many $ portDef
76     net <- many netSpec
77     return AST.ModuleBody
78         { AST.ports     = concat ports
79         , AST.moduleNet = net
80         }
81
82 portDef = choice [inputPorts, outputPorts]
83     where
84         inputPorts = do
85             reserved "input"
86             ports <- commaSep1 identifierFor
87             return $ map toInDef ports
88         toInDef (forFn, iden) =
89             let
90                 portDef = AST.InputPortDef iden
91             in case forFn of
92                 Nothing -> portDef
93                 Just f  -> AST.MultiPortDef $ f portDef
94         outputPorts = do
95             reserved "output"
96             ports <- commaSep1 identifierFor
97             return $ map toOutDef ports
98         toOutDef (forFn, iden) =
99             let
100                 portDef = AST.OutputPortDef iden
101             in case forFn of
102             Nothing -> portDef
103             Just f  -> AST.MultiPortDef $ f portDef
104
105 netSpec = choice [ inst <?> "module instantiation"
106                  , decl <?> "node declaration"
107                  , multiSpecs
108                  ]
109     where
110         inst = do
111             moduleInst <- moduleInst
112             return $ AST.ModuleInstSpec moduleInst
113         decl = do
114             nodeDecls <- nodeDecls
115             return $ AST.NodeDeclSpec nodeDecls
116         multiSpecs = do
117             for <- for $ many1 netSpec
118             return $ AST.MultiNetSpec for
119
120 moduleInst = do
121     (name, args) <- try $ do
122         name <- moduleName
123         args <- option [] $ parens (commaSep moduleArg)
124         symbol "as"
125         return (name, args)
126     nameSpace <- identifier
127     portMappings <- option [] $ symbol "with" *> many1 portMapping
128     return AST.ModuleInst
129         { AST.moduleName = name
130         , AST.nameSpace  = nameSpace
131         , AST.arguments  = args 
132         , AST.portMappings = portMappings
133         }
134
135 moduleArg = choice [addressArg, numberArg, paramArg]
136     where
137         addressArg = do
138             addr <- addressLiteral
139             return $ AST.AddressArg (fromIntegral addr)
140         numberArg = do
141             num <- numberLiteral
142             return $ AST.NumberArg (fromIntegral num)
143         paramArg = do
144             name <- parameterName
145             return $ AST.ParamArg name
146
147 portMapping = choice [inputMapping, outputMapping]
148     where
149         inputMapping = do
150             (forFn, mappedId) <- try $ identifierFor <* symbol ">"
151             portId <- identifier
152             return $ let
153                 portMap = AST.InputPortMap
154                     { AST.mappedId = mappedId
155                     , AST.portId   = portId
156                     }
157                 in case forFn of
158                     Nothing -> portMap
159                     Just f  -> AST.MultiPortMap $ f portMap
160         outputMapping = do
161             (forFn, mappedId) <- try $ identifierFor <* symbol "<"
162             portId <- identifier
163             return $ let
164                 portMap = AST.OutputPortMap
165                     { AST.portId   = portId
166                     , AST.mappedId = mappedId
167                     }
168                 in case forFn of
169                     Nothing -> portMap
170                     Just f  -> AST.MultiPortMap $ f portMap
171
172 nodeDecls = do
173     nodeIds <- choice [try single, try multiple]
174     nodeSpec <- nodeSpec
175     return $ map (toNodeDecl nodeSpec) nodeIds
176     where
177         single = do
178             nodeId <- identifier
179             reserved "is"
180             return [(Nothing, nodeId)]
181         multiple = do
182             nodeIds <- commaSep1 identifierFor
183             reserved "are"
184             return nodeIds
185         toNodeDecl nodeSpec (forFn, ident) = let
186             nodeDecl = AST.NodeDecl
187                 { AST.nodeId = ident
188                 , AST.nodeSpec = nodeSpec
189                 }
190             in case forFn of
191                 Nothing -> nodeDecl
192                 Just f  -> AST.MultiNodeDecl $ f nodeDecl
193
194 identifier = do
195     (_, ident) <- identifierHelper False
196     return ident
197
198 nodeSpec = do
199     nodeType <- optionMaybe $ try nodeType
200     accept <- option [] accept 
201     translate <- option [] tranlsate 
202     overlay <- optionMaybe overlay
203     return AST.NodeSpec 
204         { AST.nodeType  = nodeType
205         , AST.accept    = accept
206         , AST.translate = translate
207         , AST.overlay   = overlay
208         }
209     where
210         accept = do
211             reserved "accept"
212             brackets $ many blockSpec
213         tranlsate = do
214             reserved "map"
215             brackets $ many mapSpec
216         overlay = do
217             reserved "over"
218             identifier
219
220 nodeType = choice [memory, device]
221     where memory = do
222             symbol "memory"
223             return AST.Memory
224           device = do
225             symbol "device"
226             return AST.Device
227
228 blockSpec = choice [range, length, singleton]
229     where
230         singleton = do
231             address <- address
232             return $ AST.SingletonBlock address
233         range = do
234             base <- try $ address <* symbol "-"
235             limit <- address
236             return $ AST.RangeBlock base limit
237         length = do
238             base <- try $ address <* symbol "/"
239             bits <- decimal <?> "number of bits"
240             return $ AST.LengthBlock base (fromIntegral bits)
241
242 address = choice [address, param]
243     where
244         address = do
245             addr <- addressLiteral
246             return $ AST.NumberAddress (fromIntegral addr)
247         param = do
248             name <- parameterName
249             return $ AST.ParamAddress name
250
251 mapSpec = do
252     block <- blockSpec
253     reserved "to"
254     dests <- commaSep1 $ mapDest
255     return $ AST.MapSpec block dests
256
257 mapDest = choice [baseAddress, direct]
258     where
259         direct = do
260             destNode <- identifier
261             return $ AST.DirectMap destNode
262         baseAddress = do
263             destNode <- try $ identifier <* reserved "at"
264             destBase <- address
265             return $ AST.BaseAddressMap destNode destBase
266
267 for body = do
268     reserved "for"
269     varRanges <- commaSep1 $ forVarRange False
270     body <- braces body
271     return AST.For
272         { AST.varRanges = varRanges
273         , AST.body      = body
274         }
275
276 identifierFor = identifierHelper True
277
278 forVarRange optVarName
279     | optVarName = do 
280         var <- option "#" (try $ variableName <* reserved "in")
281         range var
282     | otherwise = do
283         var <- variableName
284         reserved "in"
285         range var
286     where
287         range var = brackets (do
288             start <- index
289             symbol ".."
290             end <- index
291             return AST.ForVarRange
292                 { AST.var   = var
293                 , AST.start = start
294                 , AST.end   = end
295                 }
296             )
297             <?> "range ([a..b])"
298         index = choice [numberIndex, paramIndex]
299         numberIndex = do
300             num <- numberLiteral
301             return $ AST.NumberLimit (fromIntegral num)
302         paramIndex = do
303             name <- parameterName
304             return $ AST.ParamLimit name
305
306 {- Helper functions -}
307 lexer = P.makeTokenParser (
308     javaStyle  {
309         {- list of reserved Names -}
310         P.reservedNames = keywords,
311
312         {- valid identifiers -}
313         P.identStart = letter,
314         P.identLetter = identLetter,
315
316         {- comment start and end -}
317         P.commentStart = "/*",
318         P.commentEnd = "*/",
319         P.commentLine = "//",
320         P.nestedComments = False
321     })
322
323 whiteSpace    = P.whiteSpace lexer
324 reserved      = P.reserved lexer
325 parens        = P.parens lexer
326 brackets      = P.brackets lexer
327 braces        = P.braces lexer
328 symbol        = P.symbol lexer
329 stringLiteral = P.stringLiteral lexer
330 commaSep      = P.commaSep lexer
331 commaSep1     = P.commaSep1 lexer
332 identString    = P.identifier lexer
333 hexadecimal   = symbol "0" *> P.hexadecimal lexer <* whiteSpace
334 decimal       = P.decimal lexer <* whiteSpace
335
336 keywords = ["module",
337             "input", "output",
338             "for", "in",
339             "as", "with",
340             "is", "are",
341             "accept", "map",
342             "over",
343             "to", "at"]   
344
345 identStart     = letter
346 identLetter    = alphaNum <|> char '_' <|> char '-'
347
348 moduleName     = identString <?> "module name"
349 parameterName  = identString <?> "parameter name"
350 variableName   = identString <?> "variable name"
351 identifierName = try ident <?> "identifier"
352     where
353         ident = do
354             start <- identStart
355             rest <- many identLetter
356             let ident = start:rest
357             if ident `elem` keywords
358                 then unexpected $ "reserved word \"" ++ ident ++ "\""
359                 else return ident
360
361 numberLiteral  = try decimal <?> "number literal"
362 addressLiteral = try hexadecimal <?> "address literal (hex)"
363
364 identifierHelper inlineFor = do
365     (varRanges, Just ident) <- choice [template identifierName, simple identifierName] <* whiteSpace
366     let
367         forFn = case varRanges of
368          [] -> Nothing
369          _  -> Just $ \body -> AST.For
370                 { AST.varRanges = varRanges
371                 , AST.body      = body
372                 }
373     return (forFn, ident)
374     where
375         simple ident = do
376             name <- ident
377             return $ ([], Just $ AST.SimpleIdent name)
378         template ident = do
379             prefix <- try $ ident <* symbol "{"
380             (ranges, varName, suffix) <- if inlineFor 
381                 then choice [forTemplate, varTemplate]
382                 else varTemplate
383             let
384                 ident = Just AST.TemplateIdent
385                     { AST.prefix = prefix
386                     , AST.varName = varName
387                     , AST.suffix = suffix
388                     }
389             return (ranges, ident)
390         varTemplate = do
391             varName <- variableName
392             char '}'
393             (ranges, suffix) <- templateSuffix
394             return (ranges, varName, suffix)
395         forTemplate = do
396             optVarRange <- forVarRange True
397             char '}'
398             (subRanges, suffix) <- templateSuffix
399             return $ let
400                 varName = mapOptVarName subRanges (AST.var optVarRange)
401                 varRange = optVarRange { AST.var = varName }
402                 ranges = varRange:subRanges
403                 in (ranges, varName, suffix)
404         templateSuffix = option ([], Nothing) $ choice
405             [ template $ many identLetter
406             , simple $ many1 identLetter
407             ]
408         mapOptVarName prev "#" = "#" ++ (show $ (length prev) + 1)
409         mapOptVarName _ name = name